mirror of
http://git.haproxy.org/git/haproxy.git
synced 2026-02-18 06:16:36 +02:00
1d2490c5ae
The pools memory usage calculation was done using ints by default, making it harder to identify large ones. Let's switch to unsigned long for the size calculations.
22 lines
686 B
Plaintext
22 lines
686 B
Plaintext
# dump pool contents (2.9 and above, with buckets)
|
|
define pools_dump
|
|
set $h = $po
|
|
set $p = *(void **)$h
|
|
while ($p != $h)
|
|
set $e = (struct pool_head *)(((char *)$p) - (unsigned long)&((struct pool_head *)0)->list)
|
|
|
|
set $total = 0
|
|
set $used = 0
|
|
set $idx = 0
|
|
while $idx < sizeof($e->buckets) / sizeof($e->buckets[0])
|
|
set $total=$total + $e->buckets[$idx].allocated
|
|
set $used=$used + $e->buckets[$idx].used
|
|
set $idx=$idx + 1
|
|
end
|
|
|
|
set $mem = (unsigned long)$total * $e->size
|
|
printf "list=%#lx pool_head=%p name=%s size=%u alloc=%u used=%u mem=%lu\n", $p, $e, $e->name, $e->size, $total, $used, $mem
|
|
set $p = *(void **)$p
|
|
end
|
|
end
|